---
title: "OnPlayerClickPlayerTextDraw | open.mp"
description: "Deze callback wordt aangeroepen wanneer een speler op een player-textdraw klikt."
canonical: https://omp.itsneufox.com/nl/docs/scripting/callbacks/OnPlayerClickPlayerTextDraw
language: nl
---

# OnPlayerClickPlayerTextDraw

## Beschrijving

Deze callback wordt aangeroepen wanneer een speler op een player-textdraw klikt. Hij wordt niet aangeroepen wanneer de speler de selectiemodus annuleert met ESC – dan wordt [OnPlayerClickTextDraw](https://omp.itsneufox.com/nl/docs/scripting/callbacks/OnPlayerClickTextDraw) aangeroepen.

| Naam | Beschrijving |
| --- | --- |
| playerid | Het ID van de speler die op de textdraw klikte. |
| PlayerText:playertextid | Het ID van de player-textdraw waarop is geklikt. |

## Returns

Wordt altijd als eerste aangeroepen in filterscripts; return 1 blokkeert ook andere scripts.

## Voorbeelden

```c
new PlayerText:gPlayerTextDraw[MAX_PLAYERS];

public OnPlayerConnect(playerid)
{
    // Create the textdraw
    gPlayerTextDraw[playerid] = CreatePlayerTextDraw(playerid, 10.000000, 141.000000, "MyTextDraw");
    PlayerTextDrawTextSize(playerid, gPlayerTextDraw[playerid], 60.000000, 20.000000);
    PlayerTextDrawAlignment(playerid, gPlayerTextDraw[playerid], TEXT_DRAW_ALIGN_LEFT);
    PlayerTextDrawBackgroundColor(playerid, gPlayerTextDraw[playerid], 0x000000FF);
    PlayerTextDrawFont(playerid, gPlayerTextDraw[playerid], TEXT_DRAW_FONT_1);
    PlayerTextDrawLetterSize(playerid, gPlayerTextDraw[playerid], 0.250000, 1.000000);
    PlayerTextDrawColor(playerid, gPlayerTextDraw[playerid], -1);
    PlayerTextDrawSetProportional(playerid, gPlayerTextDraw[playerid], true);
    PlayerTextDrawSetShadow(playerid, gPlayerTextDraw[playerid], 1);

    // Make it selectable
    PlayerTextDrawSetSelectable(playerid, gPlayerTextDraw[playerid], true);

    // Show it to the player
    PlayerTextDrawShow(playerid, gPlayerTextDraw[playerid]);
    return 1;
}

public OnPlayerKeyStateChange(playerid, KEY:newkeys, KEY:oldkeys)
{
    if (newkeys == KEY_SUBMISSION)
    {
        SelectTextDraw(playerid, 0xFF4040AA);
    }
    return 1;
}

public OnPlayerClickPlayerTextDraw(playerid, PlayerText:playertextid)
{
    if (playertextid == gPlayerTextDraw[playerid])
    {
        SendClientMessage(playerid, 0xFFFFFFAA, "You clicked on a player-textdraw.");
        CancelSelectTextDraw(playerid);
        return 1;
    }
    return 0;
}
```

## Notities

waarschuwing

Wanneer een speler ESC drukt om de selectie te annuleren, wordt [OnPlayerClickTextDraw](https://omp.itsneufox.com/nl/docs/scripting/callbacks/OnPlayerClickTextDraw) aangeroepen met ID 'INVALID\_TEXT\_DRAW'. [OnPlayerClickPlayerTextDraw](https://omp.itsneufox.com/nl/docs/scripting/callbacks/OnPlayerClickPlayerTextDraw) wordt dan niet aangeroepen.

## Gerelateerde Callbacks

-   [OnPlayerClickTextDraw](https://omp.itsneufox.com/nl/docs/scripting/callbacks/OnPlayerClickTextDraw): Deze callback wordt aangeroepen wanneer een speler op een textdraw klikt.
-   [OnPlayerClickPlayer](https://omp.itsneufox.com/nl/docs/scripting/callbacks/OnPlayerClickPlayer): Deze callback wordt aangeroepen wanneer een speler op een andere speler klikt.

## Gerelateerde Functies

-   [PlayerTextDrawSetSelectable](https://omp.itsneufox.com/nl/docs/scripting/functions/PlayerTextDrawSetSelectable): Maakt een player-textdraw selecteerbaar via [SelectTextDraw](https://omp.itsneufox.com/nl/docs/scripting/functions/SelectTextDraw)